Stellaris - Commonwealth of man iA broken

[Nangos]

Description
Commonwealth of man iA broken

Game Version
3.0.2

What version do you use?
Steam

What expansions do you have installed?
Synthetic Dawn, Utopia, Leviathans Story Pack, Megacorp, Distant Stars, Ancient Relics, Lithoids, Federations

Do you have mods enabled?
No

Please explain your issue is in as much detail as possible.
Last game commwealth of Man had an extensive territory but only home planet and even a bunch of habitats all around but none was colonized, empire obly had home planet and crippled economy.
Today i start a new game and commonwealth of man is crappy again and i think i found the leading cause:

I play humans as void dwellers and trait unadaptable, thing is all other humans on the galaxy seems to be MY kind of human... void dwellers, so they start in their planet homes crippled af and because of some reason not being able to colonize, not even habitats.

I will be looking into more details as i progress in the game but i am quite positive on the persistence of this issue.

Cheers

Steps to reproduce the issue.
Play as human void dweller with unadaptable trait

Upload Attachment
File(s) attached

 

[Alfray Stryke]

Hi,

Thanks for your report!

We require a save game to properly investigate the issue. Please attach a zipped save here, if possible.
Save games can usually be found at:
Windows: C:\Users\[USERNAME]\Documents\Paradox Interactive\Stellaris\save games
Mac: /Users/USERNAME/Documents/Paradox Interactive/Stellaris/save games
Linux: $HOME/.local/share/Paradox Interactive/Stellaris/save games/

 

[Firegolem]

We require a save game to properly investigate the issue. Please attach a zipped save here...

I really thought save games are already zipped.

 

[Nangos]

Ok since i play ironman last game commwealth of man is gone but i played another game and the same happened.
This time i dont have unadaptable trait. Also United Nations of Earth is doing fine colonizing other planets this time.
Same situation happening, Commonwealth of man has only one planet but a big territory, maybe it is just a game mechanic but it really looks like it is malfunctioning since last time they even built orbital stations but did not used them.

Cheers

 

[The Founder]

We require a save game to properly investigate the issue.

No need for a savegame, but simple steps:
1. It is possible to make a UNS or COM derviate, that is still considered human_1 or human_2 by the game code. The trick is to modify the COM or UNS. And hope the game does not mess up saving the flags/manually fix the flags.
2. In the normal process, the Lost Colony Species is used to spawn the home System/Empire.
3. However the code that force-spawns the COM when someone playse the UNS just copies the existing human_1 species blindly.
Even if they have a special habitability - like Habitat. Or Gaia World.
The COM force spawn code should really only apply for default habitability.

 

[The Founder]

And here is a custom empire to showcase the issue:

"Human Star Empire"
={
    key="Human Star Empire"
    ship_prefix="HSES"
    species={
        class="HUM"
        portrait="human"
        name="Human"
        plural="Humans"
        adjective="Human"
        species_bio="It is hard to predict how a species would react to the realisation that they have evolved on a Gaia world. It could be seen as a cosmic death setence, since the species can not trive on many other worlds. This version of humanity had to face the realisation and turned towards authoritarian and xenophobia. If there are other planets, other species they should serve humanity!"
        name_list="HUMAN1"
        trait="trait_extremely_adaptive"
        trait="trait_decadent"
        trait="trait_wasteful"
    }
    name="Human Star Empire"
    adjective="Human"
    authority="auth_imperial"
    flags={
        "human_1"
        "custom_start_screen"
    }
    government="gov_despotic_empire"
    advisor_voice_type="l_authoritarian"
    planet_name="Earth"
    planet_class="pc_continental"
    system_name="Sol"
    initializer="sol_system_initializer"
    graphical_culture="humanoid_01"
    city_graphical_culture="humanoid_01"
    empire_flag={
        icon={
            category="human"
            file="flag_human_9.dds"
        }
        background={
            category="backgrounds"
            file="circle.dds"
        }
        colors={
            "red"
            "black"
            "null"
            "null"
        }
    }
    ruler={
        gender=female
        name="Dolores Muwanga"
        portrait="human_female_05"
        texture=0
        hair=1
        clothes=0
        leader_class="ruler"
    }
    spawn_as_fallen=no
    ignore_portrait_duplication=yes
    room="personality_federation_builders_room"
    spawn_enabled=no
    ethic="ethic_fanatic_authoritarian"
    ethic="ethic_xenophobe"
    civics={
        "civic_aristocratic_elite"
        "civic_byzantine_bureaucracy"
    }
    origin="origin_life_seeded"
}

It is the UNS, with Gaia World Origin, still tagged as human_1.
The code to force spawn the COM just puts the UNS species on a Continental Planet, where they got ~0% habitability.

 

[Nangos]

No need for a savegame, but simple steps:
1. It is possible to make a UNS or COM derviate, that is still considered human_1 or human_2 by the game code. The trick is to modify the COM or UNS. And hope the game does not mess up saving the flags/manually fix the flags.
2. In the normal process, the Lost Colony Species is used to spawn the home System/Empire.
3. However the code that force-spawns the COM when someone playse the UNS just copies the existing human_1 species blindly.
Even if they have a special habitability - like Habitat. Or Gaia World.
The COM force spawn code should really only apply for default habitability.

Hi i am not interested in fixing the problem for my gameplay but rather report a consistent issue of the game.

if this is a feature then there is no more to talk about on my side, but i don't think it is.

Cheers

 

[The Founder]

Hi i am not interested in fixing the problem for my gameplay but rather report a consistent issue of the game.

if this is a feature then there is no more to talk about on my side, but i don't think it is.

Cheers

I am not a developer, just a fellow Forum user. That did some work on the Wiki in ages past. And suffered a variant of this issue before.

Just trying to point the devs in the right direction, so they can fix that.

 

[The Founder]

And here is the piece of code that is breaking:

### Deneb System - UNE start
une_deneb_system = {
    name = "NAME_Deneb"
    class = "sc_a"
    asteroid_belt = {
        type = rocky_asteroid_belt
        radius = 90
    }

    init_effect = {
        every_neighbor_system = {
            set_star_flag = empire_cluster
            every_neighbor_system = {
                set_star_flag = empire_cluster
            }
        }
        generate_home_system_resources = yes
    }

    flags = { empire_home_system deneb_system }

    usage = misc_system_init

    usage_odds = {
        base = 0
        modifier = {
            any_country = {
                has_country_flag = human_1
                species_portrait = human
            }
            NOT = { any_system = { has_star_flag = deneb_system } }
            NOT = { has_star_flag = empire_cluster }
            num_ai_empires_setting  >= 1

            add = 99999
        }
    }

    max_instances = 1

    planet = {
        name = "NAME_Deneb"
        class = "pc_a_star"
        orbit_distance = 0
        orbit_angle = 1
        size = 40
        has_ring = no
    }

    planet = {
        name = "NAME_Inferno"
        class = "pc_molten"
        orbit_distance = 60
        orbit_angle = 45
        size = 10
        has_ring = no
    }

    planet = {
        name = "NAME_DT4-298"
        class = "pc_asteroid"
        orbit_distance = 30
        orbit_angle = 340
        size = 5
        has_ring = no
    }

    planet = {
        name = "NAME_LR-2129"
        class = "pc_asteroid"
        orbit_distance = 0
        orbit_angle = 160
        size = 5
        has_ring = no
    }

    planet = {
        name = "NAME_GR-345"
        class = "pc_asteroid"
        orbit_distance = 0
        orbit_angle = 270
        size = 5
        has_ring = no
    }

    planet = {
        name = "NAME_Olympus"
        class = "pc_gas_giant"
        orbit_distance = 30
        orbit_angle = 200
        size = 40
        has_ring = no
        entity = "gas_giant_02_entity"

        moon = {
            name = "NAME_New_Luna"
            class = "pc_frozen"
            size = 5
            orbit_distance = 18
            orbit_angle = 100
            has_ring = no
        }
        moon = {
            name = "NAME_Unity"
            class = pc_continental
            orbit_distance = 5
            orbit_angle = 340
            size = 18
            starting_planet = yes
            has_ring = no
            entity = "continental_planet_01_entity"
            deposit_blockers = none
            modifiers = none

            init_effect = {
                prevent_anomaly = yes
                random_country = {
                    limit = { has_country_flag = human_1 }
                    save_event_target_as = une
                    owner_species = {
                        save_event_target_as = human_species
                    }
                }
                create_country = {
                    name = "NAME_Commonwealth_of_Man"
                    adjective = "PRESCRIPTED_adjective_humans2"
                    authority = "auth_dictatorial"


                    civics = {
                        civic = civic_nationalistic_zeal
                        civic = civic_distinguished_admiralty
                    }
                    species = event_target:human_species
                    name_list = "HUMAN2"
                    ship_prefix = "CNS"
                    ethos = {
                        ethic = "ethic_xenophobe"
                        ethic = "ethic_fanatic_militarist"
                    }
                    flag = {
                        icon= {
                            category = "human"
                            file = "flag_human_4.dds"
                        }
                        background= {
                            category = "backgrounds"
                            file = "stripe.dds"
                        }
                        colors={
                            "red"
                            "black"
                            "null"
                            "null"
                        }
                    }
                    type = default
                    origin = "origin_lost_colony"
                    effect = {
                        save_global_event_target_as = npc_CoM
                        add_resource = {
                            minerals = 800
                            energy = 800
                            food = 800
                            alloys = 400
                            consumer_goods = 400
                            influence = 200
                        }
                        if = {
                            limit = {
                                event_target:une = {
                                    has_origin = origin_necrophage
                                }
                            }
                            set_origin = origin_necrophage
                            set_country_flag = necrophage_commonwealth
                        }
                    }
                }
                create_colony = {
                    owner = event_target:npc_CoM
                }
                generate_start_deposits_and_blockers = yes
                clear_blockers = yes
                generate_start_buildings_and_districts = yes
                generate_start_pops = yes
                event_target:npc_CoM = {
                    set_country_flag = human_2
                    set_country_flag = special_intro_for@event_target:une
                    create_starting_leaders = yes
                    country_event = { id = game_start.9 }
                    country_event = { id = game_start.33 days = 1 } # needs delay for system ownership to settle
                }
                set_name = "NAME_Unity"
            }
        }
    }

    planet = {
        name = "NAME_Marble"
        class = "pc_barren_cold"
        orbit_distance = 20
        orbit_angle = 325
        size = 10
        has_ring = no
    }

    planet = {
        name = "NAME_Hyperion"
        class = "pc_gas_giant"
        orbit_distance = 20
        orbit_angle = 110
        size = 30
        has_ring = no
        entity = "gas_giant_05_entity"

        moon = {
            name = "NAME_Helios"
            class = "pc_frozen"
            size = 8
            orbit_distance = 14
            orbit_angle = 14
            has_ring = no
        }
    }

    planet = {
        name = "NAME_Tumbleweed"
        class = "pc_barren"
        orbit_distance = 20
        orbit_angle = 35
        size = 15
        has_ring = no
    }

    planet = {
        name = "NAME_Jackson's_Planet"
        class = "pc_frozen"
        orbit_distance = 20
        orbit_angle = 150
        size = 20
        has_ring = no
    }

    init_effect = {
        create_starbase = {
            size = starbase_starport
            module = shipyard
            building = crew_quarters
            owner = event_target:npc_CoM
            effect = {
                set_starbase_module = {
                    slot = 1
                    module = trading_hub
                }
            }
        }
    }

    neighbor_system = {
        trigger = { num_guaranteed_colonies >= 2 }
        hyperlane_jumps = { min = 1 max = @jumps }
        initializer = "deneb_neighbor_t1"
    }
    neighbor_system = {
        trigger = { num_guaranteed_colonies >= 1 }
        hyperlane_jumps = { min = 1 max = @jumps }
        initializer = "deneb_neighbor_t1_first_colony"
    }
}

It will just blindly copy the human_1 empire pops:

random_country = {
    limit = { has_country_flag = human_1 }
    save_event_target_as = une
    owner_species = {
        save_event_target_as = human_species
    }
}

The useage_odds should be the part responsible for the check. It really just needs a minor expansion on the lockout conditions. I would propably try something solid like checking for the default habitabilities.
Also Unity should not be hardcoded as "continental". The normal code you are using for the major part of a Lost Colony should be used.